Anhang J

Table Of Contents

show

Programme, die Sie ausprobieren sollten

Kodeknacker
Michael Row The Boat Ashore
Alfabet
Elektronisches Klavier

Programme, die Sie ausprobieren sollten

Wir haben hier für Sie einige Programme aufgelistet, die Sie auf Ihrem Commodore 64 zur Übung eingeben können. Sie zeigen Ihnen Unterhaltendes aber auch Nützliches.

Kodeknacker

100 PRINT"{CLEAR}{DOWN}{REVERSE ON}{RIGHT*6}{SPACE*7}KODEKNACKER{SPACE*10}"
110 INPUT"{DOWN}SPIELANLEITUNG (J/N)";Z$:IFASC(Z$)=78THEN170
120 PRINT"{DOWN}DU MUSST DAS GEHEIME KODE-WORT FINDEN!"
130 PRINT"{DOWN}ES BESTEHT AUS 5 BUCHSTABEN."
140 PRINT"{DOWN}NACH JEDEM VERSUCH ERFAEHRST DU,"
150 PRINT"{DOWN}WIEVIELE BUCHSTABEN SCHON STIMMEN."
160 PRINT"{DOWN}EIN TIP: NICHT EINFACH WILD RUMRATEN!"
170 DATA CJFOF,LBUCF,UBOOF,XJFTF,CMVNF
180 DATA WBUFS,LBUFS,MFEFS,QGFSE,TUBMN
190 DATA TUSPI,MFISF,TUPGG,OVQQF,MFJOF
200 DATA MJTUF,LBOOF,SJOOF,TVQQF,MJFCF
210 DATA SFJTF,NFJTF,HBSCF,GBSCF,MJFCF
220 DATA CVOHF,MVOHF,KVOHF,CBOHF,MBOHF
230 DATA IFUCF,LFUUF,SBUUF,NFJTF,UBTUF
240 DATA EBOLF,QBSLB,UJTDI,TUVIM,IBBSF
250 DATA TQJFM,TQVSU,TQPSU,LBNQG,XFUUF
260 DATA CVDIF,CJSLF,QFTQF,IBGFS,GFSOF
270 N=50
280 DIMN$(N),Z(5),Y(5)
290 FORJ=1TON:READN$(J):NEXTJ
300 T=TI
310 T=T/1000:IFT>=1THEN310
320 Z=RND(-T)
330 G=0:N$=N$(RND(1)*N+1)
340 PRINT"{DOWN}{REVERSE ON}KNACK MEINEN GEHEIM-KODE!":IFR>0THEN380
350 PRINT"{DOWN}ES IST EIN SINNVOLLES 5-BUCHSTABENWORT."
360 PRINT"{DOWN}DU DARFST RATEN, UND ICH SAGE DIR,"
370 PRINT"{DOWN}WIEVIELE BUCHSTABEN STIMMEN."
380 G=G+1:INPUT" DEIN VERSUCH ";Z$
390 IF LEN(Z$)<>5 THENPRINT"{REVERSE ON}5 BUCHSTABEN!":GOTO380
400 V=0:M=0:H=0
410 FORJ=1TO5
420 Z=ASC(MID$(Z$,J,1)):Y=ASC(MID$(N$,J,1))-1:IFY=64THENY=90
430 IFZ<65ORZ>90THENPRINT" {REVERSE ON}UNGUELTIGER KODE!":GOTO380
440 IFZ=65ORZ=69ORZ=73ORZ=79ORZ=85ORZ=89THENV=V+1
450 IFZ=YTHENM=M+1
460 Z(J)=Z:Y(J)=Y:NEXTJ
470 IFM=5THEN580
480 IFV=0ORV=5THENPRINT"{REVERSE ON}WAS SOLL DER QUATSCH?":GOTO380
490 FORJ=1TO5:Y=Y(J)
500 FORK=1TO5:IFY=Z(K)THENH=H+1:Z(K)=0:GOTO520
510 NEXTK
520 NEXTJ
530 PRINT"{UP}{RIGHT*22}";H;"TREFFER"
540 IFG<30THEN380
550 PRINT" {REVERSE ON}GIB'S AUF ! DER KODE HEISST '";
560 FORJ=1TO5:PRINTCHR$(Y(J));:NEXTJ
570 PRINT"'":GOTO590
580 PRINT" DU HAST ES IN"G"VERSUCHEN GESCHAFFT!"
590 INPUT"{REVERSE ON}EIN NEUER KODE";Z$
600 R=1:IFASC(Z$)<>78THEN330

Michael Row The Boat Ashore

100 REM MICHAEL ROW THE BOAT ASHORE
110 SI=54272:W1=SI+4:W2=SI+11:W3=SI+18
120 F0(0)=3000:F0(1)=1508:F0(2)=6030
130 D0=180
140 HT=2^(1/12) :REM HALBTONSCHRITT
150 DEFFNH(F)=INT(F/256):REM HI-BYTE
160 DEFFNL(F)=F-256*FNH(F):REM LO-BYTE
170 FORK=0TO20:READX:POKESI+K,X:NEXT:REM KLANGEINSTELLUNGEN
180 READWA,WB,WC:REM WELLENFORMEN
190 DIMF(100,6)
200 PRINT"{CLEAR} STIMME 1 STIMME 2 STIMME 3 DAUER"
210 N=N+1:FOR K=0TO2:READF :REM NOTE AUSDATA
220 F=INT(F0(K)*HT^F+.5):HB=FNH(F):LB=FNL(F):PRINTHB;LB,:REM HI UND LO BYTE
230 F(N,2*K)=LB:F(N,2*K+1)=HB
240 NEXTK
250 READD:PRINT" "D:F(N,6)=D:REM DAUER
260 IFD>0THEN210
270 POKESI+24,15
280 FORI=1TON-1
290 FORK=0TO2:POKESI+7*K,F(I,2*K):POKESI+7*K+1,F(I,2*K+1):NEXTK:REM 3 FREQ.
300 POKEW1,WA:POKEW2,WB:POKEW3,WC
310 FORK=1TOF(I,6)*D0-150:NEXT
320 POKEW1,0:POKEW2,0:POKEW3,0:REM GENERATOREN AUSSCHALTEN
330 FORK=1TO50:NEXT
340 NEXTI
350 GOTO 280
360 DATA0,0,0,1,0,0,255 :REM SID REGISTER
370 DATA0,0,0,1,0,0,255
380 DATA0,0,0,1,0,0,255
390 DATA37,33,33:REM WELLENFORM
400 DATA0,0,0,2 :REM MELODIE
410 DATA4,0,0,2
420 DATA7,4,0,3
430 DATA 4,0,0,1
440 DATA 7,4,0,2
450 DATA 9,5,0,2
460 DATA 7,4,-5,3
470 DATA -99,-99,-99,1
480 DATA 4,0,0,2
490 DATA 7,0,0,2
500 DATA 9,5,5,8
510 DATA 7,4,0,3
520 DATA -99,-99,-99,1
530 DATA 4,0,0,2
540 DATA 7,4,0,2
550 DATA 7,4,0,3
560 DATA 4,0,0,1
570 DATA 5,2,0,2
580 DATA 4,0,0,2
590 DATA 2,-1,-5,3
600 DATA -99,-99,-99,1
610 DATA 0,-5,0,2
620 DATA 2,-1,0,2
630 DATA 4,0,0,4
640 DATA 2,-5,-5,4
650 DATA 0,0,0,3
660 DATA-99,-99,-99,1
670 DATA -99,-99,-99,-1

Alfabet

100 REM ALFABET
110 DIMA$(26)
120 Z$="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
130 Z1$="12345678901234567890123456"
140 PRINT"{CLEAR}ZIEL DES SPIEL IST ES, EINE FOLGE VON"
150 PRINT"{DOWN}BUCHSTABEN ALFABETISCH ZU ORDNEN."
160 PRINT"{DOWN}DAZU DUERFEN SIE JEWEILS DEN ANFANG"
170 PRINT"{DOWN}DER FOLGE UMDREHEN. VIEL ERFOLG!"
180 PRINT"{DOWN*2}WIE LANG SOLL DIE FOLGE SEIN {DOWN}"
190 INPUT"MAXIMAL 26 ";S
200 IFS<1ORS>26THEN180
210 FORI=1TOS:A$(I)=MID$(Z$,I,1):NEXTI
220 REM ZUFALLSVERTAUSCHUNG
230 FORI=1TOS:K=INT(RND(1)*S+1)
    240 T$=A$(I):A$(I)=A$(K):A$(K)=T$
250 NEXTI
260 GOSUB470:T=0
270 REM TEILSTRING UMDREHEN
280 T=T+1
290 INPUT"WIE VIELE SOLL ICH UMDREHEN";R%
300 IFR%=0THEN430
310 IFR%>0ANDR%<=STHEN330
320 PRINT"MUSS ZWISCHEN 1 UND"S"LIEGEN!":GOTO290
330 R=INT(R%/2):FORI=1TOR
340 T$=A$(I)
350 T$=A$(I):A$(I)=A$(R%-I+1):A$(R%-I+1)=T$
360 NEXTI:GOSUB470
370 REM REIHENFOLGE PRUEFEN
380 C=1:FORI=2TOS
390 IFA$(I)>A$(I-1)THEN410
400 C=0
410 NEXTI
420 IFC=0THEN270
430 PRINT"{DOWN}{REVERSE ON}IN"T"{LEFT} ZUEGEN GESCHAFFT!"
440 INPUT"{DOWN}NOCHMAL";Y$
450 IFLEFT$(Y$,1)="J"ORY$="OK"ORY$="1"THEN180
460 END
470 PRINT:PRINTLEFT$(Z1$,S)
480 FORI=1TOS:PRINTA$(I);:NEXTI
490 PRINT"{DOWN}":RETURN

Elektronisches Klavier

100 REM ELEKTRONISCHES KLAVIER
110 PRINT"{CLEAR} {REVERSE ON} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {RIGHT} {221} "
120 PRINT" {REVERSE ON} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {RIGHT} {221} "
130 PRINT" {REVERSE ON} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {221} {RIGHT} {RIGHT} {RIGHT} {221} "
140 PRINT" {REVERSE ON} {221} {221} {221} {221} {221} {221} {221} {221} {221} {221} {221} {221} {221} {221} "
150 PRINT" {REVERSE ON}Q{221}W{221}E{221}R{221}T{221}Y{221}U{221}I{221}O{221}P{221}@{221}*{221}^{221};{221}="
160 PRINT"{DOWN} 'LEERTASTE':{SPACE*5}PEDAL"
170 PRINT"{DOWN}'F1','F3','F5','F7': OKTAVE"
180 PRINT"{DOWN}'F2','F4','F6','F8': WELLENFORM"
190 PRINT" {DOWN}GEDULD, ICH MUSS RECHNEN!"
200 SI=13*4096+1024:DIMF(26):DIMK(255)
210 FORI=0TO28:POKESI+I,0:NEXT
220 F1=7939:FORI=1TO26:F(27-I)=F1*5.8+30:F1=F1/2^(1/12):NEXT
230 K$="1Q2W3ER5T6Y7UI9O0P@-*\^{HOME};=":REM BENUETZTE TASTEN
240 FORI=1TOLEN(K$):K(ASC(MID$(K$,I)))=I:NEXT
250 PRINT"{UP}{SPACE*31}"
260 AN=0:AB=0:HA=15:AU=9:HH=HA*16+AU:AS=AN*16+AB:WF=16:M=1:OK=4:HB=256:Z=0
270 FORI=0TO2:POKESI+5+I*7,AS:POKESI+6+I*7,HT
280 POKESI+2+I*7,4000AND255:POKESI+3+I*7,4000/256:NEXT
290 POKESI+24,15+16+64 :POKESI+23,7:REM FILTER ENTFERNEN
300 GETA$:IFA$=""THEN300
310 FR=F(K(ASC(A$)))/M:FL=SI+V*7:W=FL+4:IFFR=ZTHEN420
320 POKEFL+6,Z
330 POKEFL+5,Z:REM HUELLKURVE AUSSCHALTEN
340 POKEW,8:POKEW,0:REM RESET
350 POKEFL,FR-HB*INT(FR/HB):REM FREQ LO
360 POKEFL+1,FR/HB:REM FREQ HI
370 POKEFL+6,HH:REM HALTEN
380 POKEW,WF+1:FORI=1TO50*AN:NEXT
390 POKEW,WF:REM AUS
400 IFP=1THENV=V+1:IFV=3THENV=0
410 GOTO300
415 REM FUNKTIONSTASTENABFRAGE
420 IFA$="{F1}"THENM=1:OK=4:GOTO300
430 IFA$="{F3}"THENM=2:OK=3:GOTO300
440 IFA$="{F5}"THENM=4:OK=2:GOTO300
450 IFA$="{F7}"THENM=8:OK=1:GOTO300
460 IFA$="{F2}"THENWF=16:GOTO300
470 IFA$="{F4}"THENWF=32:GOTO300
480 IFA$="{F6}"THENWF=64:GOTO300
490 IFA$="{F8}"THENWF=128:GOTO300
500 IFA$=" "THENP=1-P:HH=(HHANDNOT2)OR(NOTHHAND2):GOTO300
510 IFA$="{CLEAR}"THEN210
520 GOTO300